tests/CMakeLists.txt

cmake_minimum_required(VERSION 3.14)
project(ucxtest VERSION 3.0 DESCRIPTION "UAP Common Extensions - Tests")

# Configuration
cmake_policy(SET CMP0077 NEW)
set(CMAKE_CXX_STANDARD 17)
enable_testing()

# Load Google Test Framework
option(INSTALL_GTEST "By default googletest shall not be installed." OFF)
option(BUILD_GMOCK "In this project we do not need gmock." OFF)
include(FetchContent)
FetchContent_Declare(
        googletest
        GIT_REPOSITORY https://github.com/google/googletest.git
        GIT_TAG e2239ee6043f73722e7aa812a459f54a28552929 # release 1.11.0
)
# For Windows: Prevent overriding the parent project's compiler/linker settings
set(gtest_force_shared_crt ON CACHE BOOL "" FORCE)
FetchContent_MakeAvailable(googletest)
include(GoogleTest)
message(STATUS "Google Test made available")

add_executable(ucxtest
        test_utils.cpp
        test_allocator.cpp
        test_compare.cpp
        test_string.cpp
        test_buffer.cpp
        test_list.cpp
        test_hash_key.cpp
        test_map.cpp
        test_map_generics.c
        test_mempool.cpp
        test_printf.cpp
        selftest.cpp
        util_allocator.cpp
        )
target_include_directories(ucxtest PRIVATE ${CMAKE_SOURCE_DIR}/../src)
target_link_libraries(ucxtest ${CMAKE_BINARY_DIR}/../libucx_static${STLIB_EXT} gtest_main)
gtest_discover_tests(ucxtest)