Mercurial > hg > LightPIT / file revision

import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
    kotlin("jvm") version "1.7.21"
    war
}
group = "de.uapcore"
version = "1.0-SNAPSHOT"

repositories {
    mavenCentral()
}

tasks.withType<KotlinCompile>().configureEach {
    kotlinOptions.jvmTarget = "11"
}

// remove after removing all java sources
tasks.withType<JavaCompile>().configureEach {
    sourceCompatibility = "11"
    targetCompatibility = "11"
}

tasks.war {
    archiveFileName.set("lightpit.war")
    from("src/main/resources")
}

kotlin {
    sourceSets {
        val main by getting {
            dependencies {
                // change the following to compileOnly, if you already have them on your server
                implementation("jakarta.servlet.jsp.jstl:jakarta.servlet.jsp.jstl-api:3.0.0")
                implementation("org.glassfish.web:jakarta.servlet.jsp.jstl:3.0.1")
                implementation("org.postgresql:postgresql:42.5.1")
                compileOnly("jakarta.servlet:jakarta.servlet-api:6.0.0")
                val flexmarkVersion = "0.64.0"
                implementation("com.vladsch.flexmark:flexmark:${flexmarkVersion}")
                implementation("com.vladsch.flexmark:flexmark-util-data:${flexmarkVersion}")
                implementation("com.vladsch.flexmark:flexmark-ext-tables:${flexmarkVersion}")
                implementation("com.vladsch.flexmark:flexmark-ext-gfm-strikethrough:${flexmarkVersion}")
                implementation("io.github.java-diff-utils:java-diff-utils:4.12")
            }
        }
    }
}